# pkg-perl/debhelper -- lintian check script for checking Vcs-* headers -*- perl -*-
#
# Copyright © 2013 Niels Thykier <niels@thykier.net>
# Copyright © 2013 gregor herrmann <gregoa@debian.org>
# Copyright © 2013 Axel Beckert <abe@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at http://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

package Lintian::pkg_perl::vcs;

use strict;
use warnings;

use Moo;
use namespace::clean;

with 'Lintian::Check';

sub source {
    my ( $self ) = @_;

    my $processable = $self->processable;

    # Only for pkg-perl packages
    return
        unless $processable->field('Maintainer')
        =~ /pkg-perl-maintainers\@lists\.alioth\.debian\.org/sm;

    # Check if the Vcs headers are git
    my @non_git_vcs_fields =
        qw(Vcs-Arch Vcs-Bzr Vcs-Cvs Vcs-Darcs Vcs-Hg Vcs-Mtn Vcs-Svn);
    foreach my $field_name (@non_git_vcs_fields) {
        my $field_value = $processable->field($field_name);
        if (defined($field_value)) {
            $self->tag('vcs-not-git', "$field_name");
        }
    }

    # Check if repo is writable for the Debian Perl Group
    foreach my $field_name (@non_git_vcs_fields,
                            qw(Vcs-Git Vcs-Browser)) {
        my $field_value = $processable->field($field_name);
        if (defined($field_value) && $field_value !~ m{^https://salsa\.debian\.org/perl-team/modules/packages}i) {
            $self->tag('vcs-url-not-under-pkg-perl', "$field_value");
        }
    }
    return;
}

1;
