/* Definitions for the database of logged-in users
   Copyright (C) 1994 Free Software Foundation

This file is part of the GNU Hurd.

The GNU Hurd is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2, or (at your option)
any later version.

The GNU Hurd is distributed in the hope that it will be useful, 
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with the GNU Hurd; see the file COPYING.  If not, write to
the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  */

subsystem login 36000;

#include <hurd/hurd_types.defs>

#ifdef LOGIN_IMPORTS
LOGIN_IMPORTS
#endif

/* For each logged in user, a file is conventionally created in the 
   directory `/var/logins' with the name of the user, a hyphen, and a small
   integer.  (The suffix is there to distinguish multiple logons of the
   same user.)  On each such node an active translator should be found
   which implements this interface.  */

/* Send an immediate message to the user.  */
routine login_message_user (
	login: file_t;
	message: data_t);

/* Return a human-readable string describing the user's physical location.  */
routine login_get_location (
	login: file_t;
	out location: data_t, dealloc);

/* Return how much time has passed since the user last used an input device. */
routine login_get_idle_time (
	login: file_t;
	out idletime: time_value_t);

/* Return a list of file names for input devices being used, separated by null
   characters.  This call is optional; clients should not depend on it.  */
routine login_get_input_devices (
	login: file_t;
	out devices: data_t, dealloc);

/* Return the process collection ID for the user's login collection. */
routine login_get_login_collection (
	login: file_t;
	out id: pid_t);
