# syslin

definição de sistemas lineares

## Seqüência de Chamamento

    [sl]=syslin(dom,A,B,C [,D [,x0] ])
                [sl]=syslin(dom,N,D)
                [sl]=syslin(dom,H)

## Parâmetros

dom

  string (`'c'`, `'d'`), ou `[]` ou um escalar.

A,B,C,D

  matrizes em representação de espaço de estados (`D` opcional com valor padrão matriz nula). para sistemas impróprios, `D` é uma matriz de polinômios.

x0

  vetor (estado inicial; valor padrão é `0`)

N, D

  matrizes de polinômios

H

  matriz de razões de polinômios ou representação de espaço de estados linear

sl

  tlist (lista "`syslin`") representando o sistema linear

## Descrição

`syslin` define um sistema linear como uma lista e verifica a consistência dos dados.

`dom` especifica o domínio de tempo do sistema e pode ter um dos seguintes valores:

`dom='c'` para um sistema de tempo contínuo, `dom='d'` para um sistema de tempo discreto, `n` para um sistema amostrado com período de amostragem `n` (em segundos).

`dom=[]` se o domínio de tempo é indefinido.

Representação em espaço de estados:

    sl=syslin(dom,A,B,C [,D [,x0] ])

Representa o sistema :

          s x  = A*x + B*u
            y  = C*x + D*u
          x(0) = x0

A saída de `syslin` é uma lista da seguinte forma: `sl=tlist(['lss','A','B','C','D','X0','dt'],A,B,C,D,x0,dom)` . Note que `D` pode ser uma matriz de polinômios (sistemas impróprios).

Representação de matriz de transferência:

    sl=syslin(dom,N,D)
    sl=syslin(dom,H)

A saída de `syslin` é uma lista da seguinte forma: `sl=rlist(N,D,dom)` ou `sl=rlist(H(2),H(3),dom)`.

Sistemas lineares definidos como `syslin` podem ser manipulados como matrizes usuais (concatenação, extração, transposição, multiplicação, etc.) ambos em estado-espaço ou representação de transferência.

A maior parte das funções de controle de estado-espaço recebem uma lista `syslin` como entrada, ao invés de quatro matrizes definindo o sistema.

## Exemplos

    A=[0,1;0,0];B=[1;1];C=[1,1];
    S1=syslin('c',A,B,C)   //Definição de sistema linear
    S1("A")    //Exibição da matriz A
    S1("X0"), S1("dt") // Exibição de X0 e domínio de tempo
    s=poly(0,'s');
    D=s;
    S2=syslin('c',A,B,C,D)
    H1=(1+2*s)/s^2, S1bis=syslin('c',H1)
    H2=(1+2*s+s^3)/s^2, S2bis=syslin('c',H2)
    S1+S2
    [S1,S2]
    ss2tf(S1)-S1bis
    S1bis+S2bis
    S1*S2bis
    size(S1)

## Ver Também

- tlist
- lsslist
- rlist
- ssrand
- ss2tf
- tf2ss
- dscr
- abcd