# datatips

プロットされた曲線に情報(tips)を配置,編集するためのツール.

## 説明

このツールにより,曲線(ポリライン)上に情報を配置,移動,修正することが できます.これはプログラムまたは対話的に行うことができます. 通常使用されるモードは対話モードです:

datatipsモードは datatipToggle() または `Edit/Start datatip manager` または指定するグラフィックウインドウの ツールバーアイコンの をクリックすることにより有効にすることができます.

一度有効になると,曲線を左クリックするだけで, 情報(カレントの点に関する情報を有する小さな箱)が曲線の最も近いdatapointに 追加されます. デフォルトで各曲線は1つの情報を有することができますが, 右クリックコンテキストメニューにより複数のdatatipsを使用することが 可能です.

情報を移動するには,曲線の小さな正方形の記号の上で左ボタンを押し, 少し待ってから好きな位置にドラッグします.

情報記号の上で右クリックするとコンテキストダイアログがオープンします. このダイアログにより関連する曲線の全ての datatips に表示される専用の情報を カスタマイズすることができます.

情報記号の上で真ん中のボタンをクリックすると, 選択された情報の向きを管理することができるコンテキスト依存のダイアログが オープンされます.

## 例

        // この例はプログラムで情報を管理する手法を示します
        x1=linspace(0,1,100)';
        y1=x1.^3;
        clf();
        plot(x1,y1,x1,sinc(10*x1));
        e=gce();
        p1=e.children(1);//sinc(10*x1)
        p2=e.children(2); //x1^3
        t=datatipCreate(p1,50);
        datatipSetOrientation(t,"lower right")
        t=datatipCreate(p1,[0.8 0.5]);
        t=datatipCreate(p2,[0.1,0]);
        t=datatipCreate(p2,[0.8 0.4]);
        datatipSetOrientation(t,"upper left")

        function str=myfmt(curve,pt,index)
          str = msprintf('sinc\n%s', sci2exp(round(pt*10)/10))
        endfunction
        datatipSetDisplay(p1,myfmt) //エディタで関数を修正し,ok

        // 3D 曲線の場合
        x1=linspace(0,1.5,100)';
        y1=x1.^3;
        clf();
        param3d(x1.*cos(10*x1),x1.*sin(10*x1),x1);
        ax=gca();ax.box='off';
        ax.rotation_angles=[76 31];
        p=gce();
        t=datatipCreate(p,50);
        datatipSetOrientation(t,"lower right")
        datatipCreate(p,[0,-1.1,1.1]);

## 参照

- datatipToggle
- datatipInitStruct
- datatipCreate
- datatipMove
- datatipSetDisplay