# stringbox

Computa o retângulo de fronteira de um texto ou rótulo.

## Seqüência de Chamamento

    rect = stringbox( string, x, y, [angle, [fontStyle, [fontSize]]] )
                rect = stringbox( Handle )

## Parâmetros

rect

  uma matriz 2x4 contendo as quatro coordenadas dos vértices do retângulo de fronteira.

string

  matriz de strings a ser encerrada

x,y

  escalares reais, coordenadas do ponto inferior esquerdo dos strings.

angle

  ângulo de rotação dos strings em sentido horário e em graus ao redor do ponto `(x,y)`.

fonStyle

  inteiro especificando o tipo da fonte.

fontSize

  inteiro especificando o tamanho da fonte.

Handle

  um manipulador gráfico do tipo Text ou Label.

## Descrição

`stringbox` retorna os vértices de um retângulo de fronteira de um texto ou rótulo ou um string que será exibido de certo modo. As coordenadas são dadas com a escala gráfica corrente. O primeiro vértice corresponde às coordenadas do texto `(x,y)`, ponto superior esquerdo sem rotação, os vértices seguintes são dados em sentido horário na matriz resultante.

O resultado pode ser impreciso com um driver Postscript.

## Exemplos

    // exibindo eixos
    axes = gca() ;
    axes.axes_visible = 'on' ;
    axes.data_bounds = [ 1, 1 ; 10, 10 ] ;

    // exibindo rótulos para eixos
    xtitle( 'stringbox', 'X', 'Y' )  ;

    // obtendo a caixa de fronteixa do rótulo X
    stringbox( axes.x_label )

    // imprimindo um string
    str = [ "Scilab", "não" , "é", "Skylab" ] ;
    xstring( 4, 9, str ) ;

    //modificando o texto
    e = gce() ;
    e.font_angle = 90 ;
    e.font_size    = 6  ;
    e.font_style   = 7 ;
    e.box = 'on' ;

    // obtendo sua caixa de fronteira
    stringbox( e )
    // ou
    rect = stringbox( str, 4, 9, 90, 7, 6 )

    // clicando e descobrindo se o texto foi acertado
    hit = xclick()  ;
    hit = hit( 2 : 3 ) ;

    if hit(1) >= rect(1,1)  & hit(1) <=  rect(1,2) & hit(2) <= rect(2,2) & hit(2) >= rect(2,3) then
      disp('Você acertou o texto.') ;
    else
      disp('Você errou.')
    end;

## Ver Também

- xstring
- xstringl
- xstringb