# colorbar

Desenha uma barra de cores

## Seqüência de Chamamento

    colorbar(umin, umax [, colminmax, fmt])

## Parâmetros

umin

  escalar real, o valor mínimo associado ao esboço

umax

  escalar real, o valor máximo associado ao esboço

colminmax

  (opcional) um vetor com dois componentes inteiros

fmt

  (optional) um string para se ajustar o formato de exbição para as graduações da barra de cores

## Descrição

Desenha uma barra de cores para um plot3d, fec, Sgrayplot, etc... Esta função deve ser chamada BEFORE do plot3d, fec, Sgrayplot,... porque ela ajusta e modifica a moldura para o esboço. Desta forma, a barra de cores não é parte do esboço associado e, assim, não é modificada por uma ampliação/diminuição ou rotação.

O argumento opcional `colminmax` pode ser utilizado para precisar a primeira cor (associada a umin) e a última cor (associada a umax) do mapa de cores corrente. Por padrão `colminmax=[1 nb_colors]` onde nb_colors é o número de cores do mapa de cores corrente.

O argumento opcional `fmt` é um string com formato C, como `"%.2f"`, `"%e"`, etc...

Para os dois argumentos opcionais, você pode utilizar a sintaxe `keyword=value` que é útil para fornecer o formato sem fornecer `colminmax` (veja o útilmo exemplo).

## Examples

    // exemplo 1
    x = linspace(0,1,81);
    z = cos(2*%pi*x)'*sin(2*%pi*x);
    zm = min(z); zM = max(z);
    clf()
    xset("colormap",jetcolormap(64))
    colorbar(zm,zM)
    Sgrayplot(x,x,z)
    xtitle("The function cos(2 pi x)sin(2 pi y)")

    // exemplo 2
    x = linspace(0,1,81);
    z = cos(2*%pi*x)'*sin(2*%pi*x);
    zm = min(z); zM = max(z);
    zz = abs(0.5*cos(2*%pi*x)'*cos(2*%pi*x));
    zzm = min(zz); zzM = max(zz);
    clf();
    xset("colormap",jetcolormap(64))

    drawlater() ;
    subplot(2,2,1)
       colorbar(zm,zM)
       Sgrayplot(x,x,z, strf="031", rect=[0 0 1 1])
       xtitle("um Sgrayplot com barra de cores")
    subplot(2,2,2)
       colorbar(zm,zM)
       plot3d1(x,x,z)
       xtitle("um plot3d1 com barra de cores")
    subplot(2,2,3)
       colorbar(zzm,zzM)
       plot3d1(x,x,zz)
       xtitle("um plot3d1 com barra de cores")
    subplot(2,2,4)
       colorbar(zzm,zzM)
       Sgrayplot(x,x,zz, strf="031", rect=[0 0 1 1])
       xtitle("um Sgrayplot com barra de cores")
    drawnow() ;

    // exemplo 3
    x = linspace(0,1,81);
    zz = abs(0.5*cos(2*%pi*x)'*cos(2*%pi*x));
    zzm = min(zz); zzM = max(zz);
    [xf,yf,zf]=genfac3d(x,x,zz);
    nb_col = 64;
    clf()
    xset("colormap",hotcolormap(nb_col))
    drawlater() ;
    colorbar(zzm,zzM,fmt="%.1f")
    nbcol = xget("lastpattern")
    zcol = dsearch(zf, linspace(zzm, zzM, nb_col+1));
    plot3d(xf, yf, list(zf, zcol), flag = [-2 6 4])
    xtitle("um plot3d com cores de gradação interpolada")
    drawnow() ;
    show_window()

## See Also

- colormap