# set

Ajusta um valor de propriedade de uma objeto entidade gráfica ou de um objeto Interface do Usuário (User Interface)

## Seqüência de Chamamento

    set(prop,val)
                set(h,prop)
                set(h,prop,val)
                h.prop=val

## Parâmetros

h

  manipulador da entidade da qual a propriedade nomeada se deseja ajustar, `h` pode ser um vetor de manipuladores, em tal caso, serão ajustados valores de propriedades para todos os objetos identificados por h

prop

  string, nome da propriedade a ser ajustada.

val

  valor a ser dado à propriedade

## Descrição

Esta rotina pode ser utilizada para se recuperar o valor de uma propriedade especificada de uma entidade de gráficos ou objeto GUI. Neste caso, é equivalente a se usar o operador ponto ('.') em um manipulador. Por exemplo, `set(h,"background",5)` é equivalente a `h.background = 5`.

Nomes de propriedades são strings. O tipo do valor ajustado dependo do tipo do manipulador e da propriedade.

Para obter a lista de todas as propriedade existentes ver graphics_entities ou uicontrol para objetos de Interface do Usuário

`set` também pode ser chamado com apenas uma propriedade como argumento. Neste caso, a propriedade deve ser uma das seguintes:

current_entity or hdl

  `set('current_entity',h)` ou `set('hdl',h)` ajusta uma nova entidade como a corrente. Neste caso, o valor deve ser um manipulador gráfico.

current_figure

  `set('current_figure',fig)` ajusta uma nova figura como a corrente. É equivalente a scf. Neste caso, o valor deve ser um manipulador FIgure.

current_axes

  `set('current_axes',axes)` ajusta novos eixos como os correntes. É equivalente a sca. Neste caso, o valor deve ser um manipulador Axes.

`set` também pode ser chamado com manipuladores gráficos e com propriedades como argumentos. O manipulador deve ser de uma figura padrão ou de eixos padrões. A propriedade deve ser `"default_values"`. Neste caso, a entidade padrão é reajustada para os valores que possuía na inicialização do Scilab. `set("default_values",h)` equivale a sda ou sdf.

## Exemplos

    clf()
    set("auto_clear","off") ;
    // Exemple of a Plot 2D
    x=[-.2:0.1:2*%pi]';
    plot2d(x-.3,[sin(x-1) cos(2*x)],[1 2] );
    a=get("current_axes");
    p1=a.children.children(1);
    p2=a.children.children(2);
    // ajustando as propriedades nomeadas para os valores especificados nos objetos
    set(p2,"foreground",13);
    set(p2,"polyline_style",2);
    set(a,'tight_limits',"on");
    set(a,"box","off");
    set(a,"sub_tics",[ 7 0 ]);
    set(a,"y_location","middle")
    set(p2,'thickness',2);
    set(p1,'mark_mode',"on");
    set(p1,'mark_style',3);
    plot2d(x-2,x.^2/20);
    p3= a.children(1).children;
    set([a p1 p2 p3],"foreground",5)

## Ver Também

- get
- delete
- copy
- move
- graphics_entities
- uicontrol