# clf

カレントの図をクリアし,デフォルト値にリセットする

## 呼び出し手順

    clf(<opt_job_arg>)
                clf(h,<opt_job_arg>)
                clf(num,<opt_job_arg>)

## パラメータ

h

  図ハンドル (ハンドル型)

num

  figure_id (数値型)

<opt_job_arg>

  文字列 ( `'clear'` または `'reset'` )で, `clf`の処理を指定します.

## 説明

`clf` コマンドは図をクリアし,デフォルト値にリセットすると共に 全ての子を削除します.

`opt_job_arg` 文字列の値が `'clear'` の場合, 指定された図の全ての子が削除されます.

`opt_job_arg` 文字列の値が `'reset'` の場合, 指定された図の全ての子が削除されるだけではなく, 図のプロパティがデフォルト値 (gdf参照)にリセットされます. 唯一の例外は`axes_size`および`figure_size`プロパティ で,これらは図が他の要素に結合されている時にはリセットされません.

`clf(num)` は`figure_id==num`の図をクリア/リセットします.

`clf(h)` はハンドル`h`が指す 図をクリア/リセットします.

`clf()` はカレントの図をクリア/リセットします.

`clf` 関数は,ユーザにより追加されたメニューやuicontrolsを含む 指定したウインドウの全ての子を削除します. メニューやuicontrolsを削除しないようにするには,替わりに `delete(gca())`を使用してください.

## 例

    f4=scf(4);  //creates figure with id==4 and make it the current one
    f4.color_map = jetcolormap(64);
    f4.figure_size = [400, 200];
    plot2d()
    clf(f4,'reset')

    f0=scf(0); //creates figure with id==0 and make it the current one
    f0.color_map=hotcolormap(128); // change color map
    t=-%pi:0.3:%pi;
    plot3d1(t,t,sin(t)'*cos(t));

    clf() // equivalent to clf(gcf(),'clear')
    plot3d1(t,t,sin(t)'*cos(t));  // color_map unchanged

    clf(gcf(),'reset')
    plot3d1(t,t,sin(t)'*cos(t));  // color_map changed (back to the default one with 32 colors)

## 参照

- set
- get
- gcf
- gdf
- scf
- graphics_entities