# csim

線形システムのシミュレーション (時間応答)

## 呼び出しの手順

    [y [,x]]=csim(u,t,sl,[x0 [,tol]])

## パラメータ

u

  関数, リストまたは文字列 (制御入力)

t

  時間を指定するための実数ベクトルで、`t(1)` は 初期時間 (`x0=x(t(1))`)を表す.

sl

  リスト (`syslin`)

y

  `y=[y(t(i)]`, i=1,..,n となる行列

x

  `x=[x(t(i)]`, i=1,..,n となる行列

tol

  ２つの要素 [atol rtol] からなるベクトルであり、それぞれ ODEソルバ(ode参照)の絶対許容誤差および相対許容誤差を定義する

## 説明

線形制御系 `sl`のシミュレーションを行う. `sl`は、 `syslin`リストで表された連続時間システムの 入力を前提とする.

`u` は制御入力、`x0` は状態量初期値である.

`y` は出力、`x` は状態量である.

制御入力は以下のいずれかとすることができる:

1. 関数 : `[inputs]=u(t)`

2. リスト : `list(ut,parameter1,....,parametern)`. ただし、`inputs=ut(t,parameter1,....,parametern)` (`ut` は関数)

3. インパルス応答の計算を表す文字列 `"impuls"` (ここで、`sl` は直達項を有さず、`x0=0`である SISO系であると仮定)

4. ステップ応答の計算を表す文字列 `"step"` (ここで、`sl` は直達項を有さず、`x0=0`である SISO系であると仮定)

5. t の各値に対応する u　の値を指定するベクトル.

## 例

    s=poly(0,'s');rand('seed',0);w=ssrand(1,1,3);w('A')=w('A')-2*eye();
    t=0:0.05:5;
    //impulse(w) = step (s * w)
    clf(0);xset("window",0);show_window();
    plot2d([t',t'],[(csim('step',t,tf2ss(s)*w))',0*t'])
    clf(1);xset("window",1);show_window();
    plot2d([t',t'],[(csim('impulse',t,w))',0*t'])
    //step(w) = impulse (s^-1 * w)
    clf(3);xset("window",3);show_window();
    plot2d([t',t'],[(csim('step',t,w))',0*t'])
    clf(4);xset("window",4);show_window();
    plot2d([t',t'],[(csim('impulse',t,tf2ss(1/s)*w))',0*t'])

    //input defined by a time function
    deff('u=input(t)','u=abs(sin(t))')
    clf();plot2d([t',t'],[(csim(input,t,w))',0*t'])

## 参照

- syslin
- dsimul
- flts
- ltitr
- rtitr
- ode
- impl