# Matplot1

Esboço 2d de matrizes utilizando cores

## Seqüência de Chamamento

    Matplot1(a,rect)

## Parâmetros

a

  matriz de reais de tamanho (n1,n2).

rect

  `[xmin,ymin,xmax,ymax]`

## Descrição

As entradas da matriz `int(a)` são utilizadas como entradas de mapa de cores no mapa de cores corrente. `rect` especifica um retângulo na escala corrente e a matriz é desenhada dentro deste retângulo. Cada entrada da matriz será renderizada como um pequeno retângulo preenchido com sua cor associada.

## Exemplos

    //--- primeiro exemplo
    clf();
    ax=gca();//obtendo o manipulador dos eixos correntes
    ax.data_bounds=[0,0;10,10];//set the data_bounds
    ax.box='on'; //desenha uma caixa
    a=5*ones(11,11); a(2:10,2:10)=4; a(5:7,5:7)=2;
    // primeira matriz no retângulo [1,1,3,3]
    Matplot1(a,[1,1,3,3])
    a=ones(10,10); a= 3*tril(a)+ 2*a;
    // segunda matriz no retângulo [5,6,7,8]
    Matplot1(a,[5,6,7,8])

    //--- segundo exemplo (animação)
    n=100;

    clf();
    f=gcf();//obtendo o manipulador da figura corrente
    f.pixmap='on';//modo de buffer duplo
    ax=gca();//obtendo o manipulador dos eixos corrente
    ax.data_bounds=[0,0;10,10];//ajustando the data_bounds
    ax.box='on'; //desenhando uma caixa
    show_pixmap()
    for k=-n:n,
      a=ones(n,n);
      a= 3*tril(a,k)+ 2*a;
      a= a + a';
      k1= 3*(k+100)/200;
      if k>-n then delete(gce()),end
      Matplot1(a,[k1,2,k1+7,9])
      show_pixmap() //enviando o buffer duplo para a tela
      sleep(8);
    end
    f.pixmap='off';

## Ver Também

- colormap
- plot2d
- Matplot
- grayplot
- Matplot_properties