# colorbar

カラーバーを描画

## 呼び出し手順

    colorbar(umin, umax [, colminmax, fmt])

## パラメータ

umin

  実数スカラー, プロットの最小値

umax

  実数スカラー, プロットの最大値

colminmax

  (オプション) 2整数の要素を有するベクトル

fmt

  (オプション) カラーバーのグラデーションの表示形式を設定する ための文字列

## 説明

plot3d, fec, Sgrayplot, etc...用にカラーバーを描画します. この関数は, plot3d, fec, Sgrayplot,... の前に コールする必要があります. これは,この関数がプロットのフレームの設定を変更するためです. この方法では,カラーバーは関連するプロットの一部ではなく,このため, ズームや回転による修正はできません.

オプションの引数 `colminmax` は, カレントのカラーマップの (uminに関連する)最初の色と(umaxに関連する)最後の色を正確に 指定するために使用できます. デフォルトでは `colminmax=[1 nb_colors]` です.ただし, nb_colors はカレントのカラーマップの色数です.

オプションの引数`fmt` は, `"%.2f"`, `"%e"`, etc...のような C言語形式を含む文字列です.

この2つのオプションのパラメータについて, 構文 `keyword=value` を使用することができます (最後の例を参照ください).

## 例

    // 例 1
    x = linspace(0,1,81);
    z = cos(2*%pi*x)'*sin(2*%pi*x);
    zm = min(z); zM = max(z);
    clf()
    xset("colormap",jetcolormap(64))
    colorbar(zm,zM)
    Sgrayplot(x,x,z)
    xtitle("The function cos(2 pi x)sin(2 pi y)")

    // 例 2
    x = linspace(0,1,81);
    z = cos(2*%pi*x)'*sin(2*%pi*x);
    zm = min(z); zM = max(z);
    zz = abs(0.5*cos(2*%pi*x)'*cos(2*%pi*x));
    zzm = min(zz); zzM = max(zz);
    clf();
    xset("colormap",jetcolormap(64))

    drawlater() ;
    subplot(2,2,1)
       colorbar(zm,zM)
       Sgrayplot(x,x,z, strf="031", rect=[0 0 1 1])
       xtitle("a Sgrayplot with a colorbar")
    subplot(2,2,2)
       colorbar(zm,zM)
       plot3d1(x,x,z)
       xtitle("a plot3d1 with a colorbar")
    subplot(2,2,3)
       colorbar(zzm,zzM)
       plot3d1(x,x,zz)
       xtitle("a plot3d1 with a colorbar")
    subplot(2,2,4)
       colorbar(zzm,zzM)
       Sgrayplot(x,x,zz, strf="031", rect=[0 0 1 1])
       xtitle("a Sgrayplot with a colorbar")
    drawnow() ;

    // 例 3
    x = linspace(0,1,81);
    zz = abs(0.5*cos(2*%pi*x)'*cos(2*%pi*x));
    zzm = min(zz); zzM = max(zz);
    [xf,yf,zf]=genfac3d(x,x,zz);
    nb_col = 64;
    clf()
    xset("colormap",hotcolormap(nb_col))
    drawlater() ;
    colorbar(zzm,zzM,[1, nb_col],fmt="%.1f")
    nbcol = xget("lastpattern")
    zcol = dsearch(zf, linspace(zzm, zzM, nb_col+1));
    plot3d(xf, yf, list(zf, zcol), flag = [-2 6 4])
    xtitle("a plot3d with shaded interpolated colors")
    drawnow() ;
    show_window()

## 参照

- colormap