# xsetech

ajusta a sub-janela de uma janela de gráficos para esboço

## Seqüência de Chamamento

    xsetech(wrect,[frect,logflag])
                xsetech(wrect=[...],frect=[..],logflag="..", arect=[...])
                xsetech()

## Parâmetros

wrect

  vetor de tamanho 4 definindo a sub-janela a ser utilizada.

frect

  vetor de tamanho 4.

logflag

  string de tamanho 2 "xy", onde x e y podem ser "n" ou "l". "n" escala normal e "l" significa escala logarítmica. x refere-se ao eixo x e y ao eixo y.

arect

  vetor de tamanho 4.

## Descrição

`xsetech` é principalmente utilizado para ajustar a sub-janela da janela de gráficos que será utilizada para esboço. A sub-janela é especificada através do parâmetro `wrect=[x,y,w,h]` (ponto superior esquerdo, largura, altura). Os valores em `wrect` a são especificados utilizando-se a proporção de largura ou altura da janela de gráficos corrente. Por exemplo, `wrect=[0,0,1,1]` significa que toda a janela será utilizada e `wrect=[0.5,0,0.5,1]` significa que a região gráfica será a metade direita da janela de gráficos.

`xsetech` também ajusta as escalas gráficas correntes para esboço 2d e pode ser utilizada juntamente a rotinas gráficas que requerem a escala de gráficos corrente (por exemplo `strf="x0z"` ou `frameflag=0` em `plot2d`).

`frect=[xmin,ymin,xmax,ymax]` é utilizado para ajustar a escala gráfica e é igual ao argumento `rect` de `plot2d`. Se `frect` não for fornecido, o valor corrente da escala de gráficos permanece inalterado. O valor padrão de `rect` é `[0,0,1,1]` (na criação de janelas, quando se volta para o valor padrão com `xset('default')` ou quando se limpa eventos gráficos gravados `clf()`).

`arect=[x_left, x_right,y_up,y_down]` é utilizado para ajustar a moldura gráfica dentro da sub-janela. A moldura gráfica é especificada (como `wrect`) utilizando-se a proporção de largura ou altura da sub-janela de gráficos corrente. O valor padrão é `1/8*[1,1,1,1]`. Se `arect` não for fornecido, o valor padrão permanece inalterado.

## Exemplos

    // para obter uma explanação gráfica dos parâmetros de xsetech entre com:
    exec('SCI/modules/graphics/demos/xsetechfig.sce');

    // aqui xsetech é usado para dividir a janela de gráficos em duas partes
    // o primeiro xsetech é usado para se ajustar a primeira sub-janela
    // e a escala de gráficos corrente
    xsetech([0,0,1.0,0.5],[-5,-3,5,3])
    // chamamos plot2d com a opção "001" para utilizar a escala de gráficos
    // ajustada por xsetech
    plot2d([1:10]',[1:10]',1,"001"," ")
    // então xsetech é usado para ajustar a segunda sub-janela
    xsetech([0,0.5,1.0,0.5])
    // a escala de gráficos é ajustada por xsetech para [0,0,1,1] por padrão
    // e nós a modificamos utilizando o argumento rect em plot2d
    plot2d([1:10]',[1:10]',1,"011"," ",[-6,-6,6,6])
    // quatro esboços em uma única janela de gráficos
    clf()
    xset("font",2,0)
    xsetech([0,0,0.5,0.5]); plot3d()
    xsetech([0.5,0,0.5,0.5]); plot2d()
    xsetech([0.5,0.5,0.5,0.5]); grayplot()
    xsetech([0,0.5,0.5,0.5]); histplot()
    // de volta aos valores padrões para a sub-janela
    xsetech([0,0,1,1])
    // um esboço com arect modificado
    clf()
    xset("default")
    xsetech(arect=[0,0,0,0])
    x=1:0.1:10;plot2d(x',sin(x)')
    clf()
    xsetech(arect=[1/8,1/8,1/16,1/4])
    x=1:0.1:10;plot2d(x',sin(x)')
    clf()
    xset("default")

## Ver Também

- xgetech
- subplot
- isoview
- square