# for

Mot-clé pour les structures de boucles

## Description

Utilisé pour spécifier une boucle. La syntaxe est la suivante :

`for variable=expression ,instruction, ,instruction,end`

`for variable=expression do instruction, ,instruction,end`

Si `expression` est une matrice ou un vecteur ligne, `variable` prend successivement les valeurs de chaque colonne de la matrice.

Un exemple utile : `for variable=n1:pas:n2, ...,end`

Si `expression` est une liste, `variable` prend comme valeurs successives les termes de la liste.

En accord avec les conventions de codage pour le langage de porgrammation Scilab, il est recommandé de :

- Commencer chaque instruction sur une nouvelle ligne.

- Ne pas écrire plus d'une instruction simple par ligne.

- Séparer les instructions composées sur plusieurs lignes.

Par exemple, utiliser :

          for i = 1:5
              disp(i);
          end

plutôt que :

          for i = 1:5 disp(i); end

Attention : le nombre de caractères constituant le corps d'une instruction conditionnelle (if while for ou select/case) est limité à 16k.

## Exemples

    // "traditional" for loops
    n=5;
    for i = 1:n
        for j = 1:n
            a(i,j) = 1/(i+j-1);
        end;
    end
    for j = 2:n-1
        a(j,j) = j;
    end;
    a
    for j= 4:-1:1
        disp(j);
    end // decreasing loop

    //loop on matrix columns
    for  e=eye(3,3), e, end
    for v=a, write(6,v), end
    for j=1:n, v=a(:,j), write(6,v), end

    //loop on list entries
    for l=list(1,2,'example'); l, end

## Voir aussi

- while
- end
- do