# drawlater

軸の子を不可視にする.

## 呼び出し手順

    drawlater()

## 説明

この関数は, プロットを行う関数のような高レベル関数をコールすることにより, または既存のオブジェクトにプロパティを設定することにより, 次に作成されるグラフィックオブジェクト, `カレントの図`にただちに 表示しない場合に使用されます.カレントの図の `immediate_drawing`プロパティは 次の描画を延期するために`'off'`に設定されます.

この関数は特に`drawnow`関数と組み合わせて使用されます.

カレントの図の`immediate_drawing`を有効に戻すには, `drawnow`関数を使用します.

警告 : drawlater と drawnow コールの間に, カレントの図が 変更される可能性があります. このため, 使用に際しては注意を要します.

## 例

    //例1 :  軸を1つ / 図を1つ
    drawlater();
    xfarc(.25,.55,.1,.15,0,64*360);
    xfarc(.55,.55,.1,.15,0,64*360);
    xfrect(.3,.8,.3,.2);
    xfrect(.2,.7,.5,.2);
    xfrect(.32,.78,.1,.1);
    xfrect(.44,.78,.14,.1);
    xfrect(-.2,.4,1.5,.8);
    xstring(0.33,.9,"A Scilab Car");
    a=get("current_axes");
    a.children(1).font_size=4;
    a.children(1).font_style=4;
    a.children(1).background=5;
    a.children(3).background=8;
    a.children(4).background=8;
    a.children(5).background=17;
    a.children(6).background=17;
    a.children(7).background=25;
    a.children(8).background=25;
    xclick();drawnow();

    //例 2: 軸を2つ / 図を1つ

    subplot(212)
    a=gca();
    drawlater //この軸に描画されるものは後で表示されます
    plot2d // これらの軸と子に後で描画します...

    subplot(211) //警告: 軸を変更します
    plot2d1 // デフォルトの描画モード

    draw(a) // ...指定した軸のみが可視で,ウインドウは再描画されません
    drawnow() // 全て可視

## 参照

- get
- set
- drawnow
- graphics_entities