# parents ( )

parenthèses droite et gauche

## Séquence d'appel

    (expression)
                [...]=func(e1,e2,...)
                [x1,x2,...]=(e1,e2,...)
                x(i,j)
                v(i)
                [...]=l(i)

## Paramètres

x

  matrice de tout type

v

  vecteur ligne ou colonne de tout type

l

  liste

func

  nom de fonction

e1,e2,...

  expression de type quelconque

## Description

Les parenthèses droite et gauche sont utilisées pour :

* Spécifier l'ordre d'évaluation dans des expressions,

* Former la liste des arguments d'entrée d'une fonction. Les arguments multiples sont séparés par des virgules,

* Sélectionner des éléments dans les vecteurs, matrices et listes.

Voir l'aide pour l'extraction et l'insertion pour de plus amples précisions.

* `[x1,x2,...]=(e1,e2,...)` est équivalent aux commandes préalables %t_1 = e1, `%t_2 = e2, ..., suivies de x1 = %t_1, x2 = %t_2, ...`, où les variables `%t_i, i = 1, 2, ...` sont "invisibles" pour l'utilisateur.

## Exemples

    3^(-1)
    x=poly(0,"x");
    //
    (x+10)/2
    i3=eye(3,3)
    //
    a=[1 2 3;4 5 6;7 8 9],a(1,3),a([1 3],:),a(:,3)
    a(:,3)=[]
    a(1,$)=33
    a(2,[$ $-1])
    a(:,$+1)=[10;11;12]
    //
    w=ssrand(2,2,2);ssprint(w)
    ssprint(w(:,1))
    ss2tf(w(:,1))
    //
    l=list(1,2,3,4)
    [a,b,c,d]=l(:)
    l($+1)='new'
    //
    v=%t([1 1 1 1 1])
    //
    [x,y,z]=(1,2,3)

## Voir aussi

- colon
- comma
- brackets
- list
- extraction
- insertion